An example of using dynamic fact descriptions in Midje

I had these tests written in Midje which had some duplication:

	(ns sorting-phones.core-test
	(:require
	[midje.sweet :refer :all]
	[sorting-phones.core :refer :all]
	[clojure.java.io :as io]))
	(let [expected-output "007334436\n053836111\n076352013\n106093560\n169322377\n172048816\n175914591\n183858586\n365661922\n532648843\n611756075\n631462297\n631988892\n897081845\n898364867\n928002342"
	output-file "resources/sorted_phones.txt"]
	(facts
	"about removing duplicates and sorting the phones in a file and writing them into another file"
	(facts
	"with a sorter that uses distinct and sort functions"
	(let [sorter (->SorterUsingDistinctAndSort)]
	(against-background
	[(after :facts (io/delete-file output-file))]
	(fact
	"when there are no duplicated phones"
	(sort! sorter "resources/phones.txt" output-file)
	(slurp output-file) => expected-output)
	(fact
	"when there are duplicated phones"
	(sort! sorter "resources/duplicated-phones.txt" output-file)
	(slurp output-file) => expected-output))))
	(facts
	"with a sorter that uses a home-made sort function to avoid using distinct function"
	(let [sorter (->HomemadeSorterThatAvoidsUsingDistinct)]
	(against-background
	[(after :facts (io/delete-file output-file))]
	(fact
	"when there are no duplicated phones"
	(sort! sorter "resources/phones.txt" output-file)
	(slurp output-file) => expected-output)
	(fact
	"when there are duplicated phones"
	(sort! sorter "resources/duplicated-phones.txt" output-file)
	(slurp output-file) => expected-output))))
	(facts
	"with a sorter that uses a sorted-set function"
	(let [sorter (->SorterUsingSortedSet)]
	(against-background
	[(after :facts (io/delete-file output-file))]
	(fact
	"when there are no duplicated phones"
	(sort! sorter "resources/phones.txt" output-file)
	(slurp output-file) => expected-output)
	(fact
	"when there are duplicated phones"
	(sort! sorter "resources/duplicated-phones.txt" output-file)
	(slurp output-file) => expected-output))))))

view raw midje_facts_with_duplication.clj hosted with ❤ by GitHub

but were providing a nice level of feedback when there was an error:

	$ lein midje
	FAIL "about removing duplicates and sorting the phones in a file and writing them into another file
	- with a sorter that uses a home-made sort function to avoid using distinct function - when there
	are duplicated phones" at (core_test.clj:53)
	...
	...

view raw initial_error_feedback.sh hosted with ❤ by GitHub

In my first attempt to remove the duplication in the facts:

	(ns sorting-phones.core-test
	(:require
	[midje.sweet :refer :all]
	[sorting-phones.core :refer :all]
	[clojure.java.io :as io]))
	(let [expected-output "007334436\n053836111\n076352013\n106093560\n169322377\n172048816\n175914591\n183858586\n365661922\n532648843\n611756075\n631462297\n631988892\n897081845\n898364867\n928002342"
	output-file "resources/sorted_phones.txt"]
	(facts
	"about removing duplicates and sorting the phones in a file and writing them into another file"
	(doseq [sorter [(->SorterUsingDistinctAndSort)
	(->HomemadeSorterThatAvoidsUsingDistinct)
	(->SorterUsingSortedSet)]]
	(against-background
	[(after :facts (io/delete-file output-file))]
	(fact
	"when there are no duplicated phones"
	(sort! sorter "resources/phones.txt" output-file)
	(slurp output-file) => expected-output)
	(fact
	"when there are duplicated phones"
	(sort! sorter "resources/duplicated-phones.txt" output-file)
	(slurp output-file) => expected-output)))))

view raw removed_facts_duplication_but_losing_feedback.clj hosted with ❤ by GitHub

I lost the level of feedback the original tests had. It didn't tell which sorter was failing:

	$ lein midje
	FAIL "about removing duplicates and sorting the phones in a file and writing them into another file
	- when there are duplicated phones" at (core_test.clj:33)
	...
	...

view raw poorer_error_feedback.sh hosted with ❤ by GitHub

By using dynamic fact descriptions (notice the use of the :midje/description metada):

	(ns sorting-phones.core-test
	(:require
	[midje.sweet :refer :all]
	[sorting-phones.core :refer :all]
	[clojure.java.io :as io]))
	(let [expected-output "007334436\n053836111\n076352013\n106093560\n169322377\n172048816\n175914591\n183858586\n365661922\n532648843\n611756075\n631462297\n631988892\n897081845\n898364867\n928002342"
	output-file "resources/sorted_phones.txt"]
	(facts
	"about removing duplicates and sorting the phones in a file and writing them into another file"
	(doseq [sorter [{:description "that uses distinct and sort functions"
	:implementation (->SorterUsingDistinctAndSort)}
	{:description "that uses a home-made sort function to avoid using distinct function"
	:implementation (->HomemadeSorterThatAvoidsUsingDistinct)}
	{:description "that uses a sorted-set function"
	:implementation (->SorterUsingSortedSet)}]]
	(let [sorter-implementation (:implementation sorter)
	description (str "with a sorter " (:description sorter))]
	(facts {:midje/description description}
	(against-background
	[(after :facts (io/delete-file output-file))]
	(fact
	"when there are no duplicated phones"
	(sort! sorter-implementation "resources/phones.txt" output-file)
	(slurp output-file) => expected-output)
	(fact
	"when there are duplicated phones"
	(sort! sorter-implementation "resources/duplicated-phones.txt" output-file)
	(slurp output-file) => expected-output)))))))

view raw facts_with_dynamic_descriptions.clj hosted with ❤ by GitHub

I was able to keep the original level of feedback and still remove the duplication:

	$ lein midje
	FAIL "about removing duplicates and sorting the phones in a file and writing them into another file
	- with a sorter that uses a home-made sort function to avoid using distinct function - when there
	are duplicated phones" at (core_test.clj:39)
	...
	...

view raw error_feedback_using_dynamic_fact_descriptions.sh hosted with ❤ by GitHub