Kata: Print Diamond in Clojure

Yesterday we did the Print Diamond kata in the Clojure Developers Barcelona group.

I paired with Rafa Gómez. We managed to complete a recursive solution to the problem using our usual mix of TDD and REPL-driven development.

Later, we showed our solution and realize that, even though, it worked fine, we had to improve the names of some helper functions we had created to make our solution easier to understand.

After that, Samuel Lê, presented on the whiteboard (we couldn't connect his laptop to the projector) a completely different and very elegant approach.

I'll try to explain it:

Say, for instance, that you're trying to create the diamond for D.

You first create the following sequence repeating the string "DCBABCD" as many times as lines there are in the diamond:

DCBABCD
DCBABCD
DCBABCD
DCBABCD
DCBABCD
DCBABCD
DCBABCD

view raw original_sequence.md hosted with ❤ by GitHub

Only one letter is allowed to appear in each line of the diamond.

Let's represent this in a table:

A -> DCBABCD
B -> DCBABCD
C -> DCBABCD
D -> DCBABCD
C -> DCBABCD
B -> DCBABCD
A -> DCBABCD

view raw diamonds_lines_table.md hosted with ❤ by GitHub

Now the only thing we have to do to get the correct diamond lines is to substitute by a space (we used an underscore to make it easier to visualize) every letter of the line that is different from the allowed letter for that line:

A -> ___A___
B -> __B_B__
C -> _C___C_
D -> D_____D
C -> _C___C_
B -> __B_B__
A -> ___A___

view raw substitution_diamond_lines.md hosted with ❤ by GitHub

This is a very elegant approach that only uses sequences functions.

When I got back home I redid the kata again using both approaches: the recursive one and the one that Samuel had explained on the whiteboard.

These are the tests I used to test drive the recursive code (sorry I can't show the REPL history because I haven't found where Cursive saves it):

	(ns print-diamond.core-test
	(:use midje.sweet)
	(:require [print-diamond.core :refer [print-diamond]]))
	(facts
	"about printing diamonds"
	(print-diamond "A") => "A"
	(print-diamond "B") => "_A_\nB_B\n_A_"
	(print-diamond "C") => "__A__\n_B_B_\nC___C\n_B_B_\n__A__"
	(print-diamond "D") => "___A___\n__B_B__\n_C___C_\nD_____D\n_C___C_\n__B_B__\n___A___")

view raw print_diamond_test.clj hosted with ❤ by GitHub

I'm using an underscore instead of a space to make the results easier to visualize.

This is the recursive code:

	(ns print-diamond.core)
	(defn- char-range [start end]
	(map char (range (int start) (inc (int end)))))
	(def ^:private alphabet (map str (char-range \A \Z)))
	(defn- spaces [n]
	(clojure.string/join (repeat n "_")))
	(defn- current-line [letter pos given-letter-pos]
	(let [spaces-side (spaces (- given-letter-pos pos))
	spaces-middle (spaces (dec (* 2 pos)))]
	(if (= letter "A")
	(str spaces-side letter spaces-side)
	(str spaces-side letter spaces-middle letter spaces-side))))
	(def ^:private previous-lines take)
	(defn- diamond-lines [pos lines middle-line]
	(clojure.string/join
	"\n"
	(concat (previous-lines pos lines)
	[middle-line]
	(reverse (previous-lines pos lines)))))
	(defn print-diamond [letter]
	(let [letter-pos (.indexOf alphabet letter)]
	(loop [letters alphabet lines [] pos 0]
	(let [current-letter (first letters)
	new-line (current-line current-letter pos letter-pos)]
	(if (= letter current-letter)
	(diamond-lines pos lines new-line)
	(recur (rest letters)
	(conj lines new-line)
	(inc pos)))))))

view raw print-diamond-recursive.clj hosted with ❤ by GitHub

Then I deleted the recursive code and started playing in the REPL to build a new solution following Samuel's approach and using the previous tests as acceptance tests to know when I was done.

Once I had it working again:

	print-diamond.core=> (print (print-diamond "Z"))
	_________________________A_________________________
	________________________B_B________________________
	_______________________C___C_______________________
	______________________D_____D______________________
	_____________________E_______E_____________________
	____________________F_________F____________________
	___________________G___________G___________________
	__________________H_____________H__________________
	_________________I_______________I_________________
	________________J_________________J________________
	_______________K___________________K_______________
	______________L_____________________L______________
	_____________M_______________________M_____________
	____________N_________________________N____________
	___________O___________________________O___________
	__________P_____________________________P__________
	_________Q_______________________________Q_________
	________R_________________________________R________
	_______S___________________________________S_______
	______T_____________________________________T______
	_____U_______________________________________U_____
	____V_________________________________________V____
	___W___________________________________________W___
	__X_____________________________________________X__
	_Y_______________________________________________Y_
	Z_________________________________________________Z
	_Y_______________________________________________Y_
	__X_____________________________________________X__
	___W___________________________________________W___
	____V_________________________________________V____
	_____U_______________________________________U_____
	______T_____________________________________T______
	_______S___________________________________S_______
	________R_________________________________R________
	_________Q_______________________________Q_________
	__________P_____________________________P__________
	___________O___________________________O___________
	____________N_________________________N____________
	_____________M_______________________M_____________
	______________L_____________________L______________
	_______________K___________________K_______________
	________________J_________________J________________
	_________________I_______________I_________________
	__________________H_____________H__________________
	___________________G___________G___________________
	____________________F_________F____________________
	_____________________E_______E_____________________
	______________________D_____D______________________
	_______________________C___C_______________________
	________________________B_B________________________
	_________________________A_________________________nil

view raw print_diamond_for_z_result.sh hosted with ❤ by GitHub

I refactored the code a bit introducing some helpers to separate responsibilities and make the code more readable and renamed some bindings.

This is the resulting code:

	(ns print-diamond.core)
	(defn- char-range [start end]
	(map char (range (int start) (inc (int end)))))
	(def ^:private alphabet (map str (char-range \A \Z)))
	(defn build-line-to-be-repeated [letter]
	(let [letters-until (concat (take-while #(not= % letter) alphabet) [letter])]
	(apply str (concat (reverse (drop 1 letters-until)) letters-until))))
	(defn substitute-spaces [line letter]
	(apply str (map #(if (= (str %) letter) letter "_") line)))
	(defn lines-number-in-uppper-triangle [letter]
	(inc (.indexOf alphabet letter)))
	(defn upper-diamond-lines [letter]
	(let [line (build-line-to-be-repeated letter)
	times (lines-number-in-uppper-triangle letter)]
	(map substitute-spaces (repeat times line) (take times alphabet))))
	(defn diamond-lines [letter]
	(let [upper-part (upper-diamond-lines letter)]
	(concat upper-part (reverse (drop-last upper-part)))))
	(defn print-diamond [letter]
	(clojure.string/join "\n" (diamond-lines letter)))

view raw print-diamond.clj hosted with ❤ by GitHub

You can find all the code in this GitHub repository.

As usual the Clojure meetup and the conversations having a drink afterwards have been both great fun and very interesting.

We also met Alejandro Gómez which is writing this great ClojureScript book and has recently moved to Barcelona.