Kata: Reverse Polish Notation Calculator in Clojure with Midje

I've just done the Reverse Polish Notation Calculator kata in Clojure using Midje.

These are the tests:

	(ns rpn.t-core
	(:use midje.sweet)
	(:use [rpn.core]))
	(facts
	"about RPN calculator"
	(fact
	"a number evaluates to itself"
	(evaluate "0") => 0
	(evaluate "1") => 1)
	(fact
	"it adds several numbers"
	(evaluate "0 1 +") => 1
	(evaluate "1 2 5 + +") => 8)
	(fact
	"it subtracts several numbers"
	(evaluate "0 1 -") => -1
	(evaluate "1 2 5 - -") => 4)
	(fact
	"it multiplies several numbers"
	(evaluate "0 1 *") => 0
	(evaluate "1 2 5 * *") => 10)
	(fact
	"it divides several numbers (integer division)"
	(evaluate "4 2 /") => 2
	(evaluate "10 5 5 / /") => 10)
	(fact
	"it computes an expression with several operators"
	(evaluate "4 2 / 5 + 10 * 5 6 - +") => 69
	(evaluate "3 2 1 + *") => 9
	(evaluate "1 2 + 4 * 5 + 3 -") => 14
	(evaluate "5 1 2 + 4 * + 3 -") => 14
	(evaluate "0 1 - 4 5 * *") => -20))

view raw rpn-tests.clj hosted with ❤ by GitHub

I really love how readable tests are when using Midje.

And this is the final version of the code:

	(ns rpn.core
	[:use [clojure [string :only [split]]]])
	(defn parse-int [s]
	(Integer/parseInt (re-find #"\A-?\d+" s)))
	(defn parse [expression]
	(let
	[operators {"+" + "-" - "*" * "/" quot}
	parse-token
	(fn [token]
	(if (contains? operators token)
	(get operators token)
	(parse-int token)))]
	(map parse-token
	(split expression #"\s"))))
	(defn process-symbol [stack symbol]
	(if (number? symbol)
	(conj stack symbol)
	(conj (pop (pop stack))
	(apply symbol (take-last 2 stack)))))
	(defn evaluate [expression]
	(peek
	(reduce
	process-symbol
	[]
	(parse expression))))

view raw rpn.clj hosted with ❤ by GitHub

I used a mix of TDD and REPL-driven development, as I did before for the Berlin Clock kata.

Again I commited the code after every passing test and every refactor and also commited the .lein-repl-history file to document all the micro-tests I did on the REPL.

Take a look at the code and commits in this GitHub repository.