Exercism: "Beer song in Clojure"

This is my solution to the Beer song problem in Clojure:

I wrote a first version using just regular functions:

	(ns beer
	(:require [clojure.string :as str]))
	(defn no-more-bottles? [num-of-bottles]
	(= num-of-bottles 0))
	(defn one-bottle? [num-of-bottles]
	(= num-of-bottles 1))
	(defn bottles [num-of-bottles]
	(cond
	(no-more-bottles? num-of-bottles) "no more bottles"
	(one-bottle? num-of-bottles) (str num-of-bottles " bottle")
	:else (str num-of-bottles " bottles")))
	(defn bottles-of-beer [num-of-bottles]
	(str (bottles num-of-bottles) " of beer"))
	(defn bottles-on-the-wall [num-of-bottles]
	(str (bottles-of-beer num-of-bottles) " on the wall"))
	(defn phrase1 [num-of-bottles]
	(str (str/capitalize (bottles-on-the-wall num-of-bottles))
	", "
	(bottles-of-beer num-of-bottles)
	".\n"))
	(defn take-down [num-of-bottles]
	(str
	"Take "
	(if (one-bottle? num-of-bottles) "it" "one")
	" down and pass it around, "))
	(defn action [num-of-bottles]
	(if (no-more-bottles? num-of-bottles)
	"Go to the store and buy some more, "
	(take-down num-of-bottles)))
	(defn remaining-bottles [num-of-bottles]
	(if (no-more-bottles? num-of-bottles)
	99
	(- num-of-bottles 1)))
	(defn phrase2 [num-of-bottles]
	(str (action num-of-bottles)
	(bottles-on-the-wall
	(remaining-bottles num-of-bottles))
	".\n"))
	(defn verse [num-of-bottles]
	(str (phrase1 num-of-bottles)
	(phrase2 num-of-bottles)))
	(defn closed-descending-range [from to]
	(reverse (range to (inc from))))
	(defn sing
	([from]
	(sing from 0))
	([from to]
	(str/join
	"\n"
	(map verse (closed-descending-range from to)))))

view raw beer1.clj hosted with ❤ by GitHub

and a second one using multimethods:

	(ns beer
	(:require [clojure.string :as str]))
	(def on-the-wall " on the wall")
	(def of-beer " of beer")
	(defn sth-of-beer [text]
	(str text of-beer))
	(defn sth-on-the-wall [text]
	(str (sth-of-beer text) on-the-wall))
	(defn take-down [which]
	(str "Take " which " down and pass it around"))
	(defn beer-phrase
	([f text]
	(beer-phrase f text ""))
	([f text plural]
	(f (str text " bottle" plural))))
	(defn paragraph [phrase1 phrase2]
	(str phrase1 ", " phrase2 ".\n"))
	(defn first-paragraph
	([text]
	(first-paragraph text ""))
	([text plural]
	(paragraph
	(str/capitalize (beer-phrase sth-on-the-wall text plural))
	(beer-phrase sth-of-beer text plural))))
	(defn second-paragraph
	([action text]
	(second-paragraph action text ""))
	([action text plural]
	(paragraph
	action
	(beer-phrase sth-on-the-wall text plural))))
	(defmulti verse identity)
	(defmethod verse 0 [_]
	(str
	(first-paragraph "no more" "s")
	(second-paragraph
	"Go to the store and buy some more" 99 "s")))
	(defmethod verse 1 [num-of-bottles]
	(str
	(first-paragraph num-of-bottles)
	(second-paragraph
	(take-down "it") "no more" "s")))
	(defmethod verse 2 [num-of-bottles]
	(str
	(first-paragraph num-of-bottles "s")
	(second-paragraph
	(take-down "one") (- num-of-bottles 1))))
	(defmethod verse :default [num-of-bottles]
	(str
	(first-paragraph num-of-bottles "s")
	(second-paragraph
	(take-down "one") (- num-of-bottles 1) "s")))
	(defn closed-descending-range [from to]
	(reverse (range to (inc from))))
	(defn sing
	([from]
	(sing from 0))
	([from to]
	(str/join
	"\n"
	(map verse (closed-descending-range from to)))))

view raw beer2.clj hosted with ❤ by GitHub

I enjoyed refactoring the code once all tests were passing.
I also practised how to use multimethods and how to pass parameters with default values.

You can nitpick my solution here or see all the exercises I've done so far in this repository.